3D.ru

Shader "Crankshaft/RaceCars/Glass" {
Properties {
        _MainTex ("Base (RGB)", 2D) = "black" {}
        _AlphaTex ("Alpha (A)", 2D) = "grey" {}
        _Cube ("Reflection Cubemap", Cube) = "_Skybox" { TexGen CubeReflect }
        _Opacity ("Opacity", Range(0,2)) = 1.0
        _Reflectivity ("Reflectivity", Range(0,1)) = 0.5
        _Fresnel( "Fresnel " , Range(0,5)) = 1.0
}
SubShader {
        LOD 200
        Tags {"Queue"="Transparent" "IgnoreProjector"="True" "RenderType"="Transparent"}
        Lighting On
       
//
//first pass
//
Cull Front
CGPROGRAM
#pragma surface surf Lambert alpha nolightmap nodirlightmap

sampler2D _MainTex;
sampler2D _AlphaTex;
float _Opacity;

struct Input {
        float2 uv_MainTex;
};

void surf (Input IN, inout SurfaceOutput o) {
        half a = tex2D(_AlphaTex, IN.uv_MainTex).a;
        o.Albedo = tex2D(_MainTex, IN.uv_MainTex).rgb;
        o.Alpha = a * _Opacity;
}
ENDCG

//
//second pass
//
Cull Back
CGPROGRAM
#pragma surface surf Lambert alpha nolightmap nodirlightmap

sampler2D _MainTex;
sampler2D _AlphaTex;
samplerCUBE _Cube;
float4 _Color;
float _Opacity;
float _Reflectivity;
float _Fresnel;

struct Input {
        float2 uv_MainTex;
        float3 viewDir;
        float3 worldRefl;
};

void surf (Input IN, inout SurfaceOutput o) {
        half a = tex2D(_AlphaTex, IN.uv_MainTex).a;
        o.Albedo = tex2D(_MainTex, IN.uv_MainTex).rgb;

        half4 reflcol = texCUBE (_Cube, IN.worldRefl);
       
        reflcol *= _Reflectivity;
        float3 view = normalize( IN.viewDir );
        float fresnel = pow(1.0 - saturate ( dot ( view, o.Normal )), _Fresnel);
         
        o.Emission = reflcol.rgb;
        o.Alpha = (_Opacity*a)+fresnel;
}
ENDCG
}
       
FallBack "Reflective/VertexLit"
}