[РЕШЕНО] Шейдер планеты атмосферы и мобильные устройства

[infernno]

Нашел модифицированный шейдер для атмосферы планеты из Unity Wiki.Но проблема в том что под мобилками не работает (см. скриншот).

Скрытый текст: показать

Shader "Space/PlanetAtmosphere"
{
Properties
{
//_Color("Color", Color) = (0, 0, 0, 1)
_AtmoColor("Atmosphere Color", Color) = (0.5, 0.5, 1.0, 1)
_Size("Size", Float) = 0.1
_Falloff("Falloff", Float) = 5
_Transparency("Transparency", Float) = 15
}

SubShader
{
Tags {
"LightMode" = "Always"
"Queue" = "Transparent+1"
"RenderType" = "Transparent"
}
Pass {
Name "AtmosphereBase"

Cull Front
Blend SrcAlpha One

CGPROGRAM
// Upgrade NOTE: excluded shader from OpenGL ES 2.0 because it does not contain a surface program or both vertex and fragment programs.
#pragma exclude_renderers gles
#pragma vertex vert
#pragma fragment frag

#pragma fragmentoption ARB_fog_exp2
#pragma fragmentoption ARB_precision_hint_fastest

#include "UnityCG.cginc"

//uniform float4 _Color;
uniform float4 _AtmoColor;
uniform float _Size;
uniform float _Falloff;
uniform float _Transparency;

struct v2f {
float4 pos : SV_POSITION;
float3 normal : TEXCOORD0;
float3 worldvertpos : TEXCOORD1;
};

v2f vert(appdata_base v) {
v2f o;

v.vertex.xyz += v.normal*_Size;
o.pos = mul (UNITY_MATRIX_MVP, v.vertex);
o.normal = v.normal;
o.worldvertpos = mul(_Object2World, v.vertex);

return o;
}

float4 frag(v2f i) : COLOR {
i.normal = normalize(i.normal);
float3 viewdir = normalize(i.worldvertpos-_WorldSpaceCameraPos);
float4 color = _AtmoColor;
color.a = pow(saturate(dot(viewdir, i.normal)), _Falloff);
//color.a *= _Transparency*_Color*dot(normalize(i.worldvertpos+_WorldSpaceLightPos0), i.normal);
color.a *= _Transparency*dot(normalize(i.worldvertpos+_WorldSpaceLightPos0), i.normal);
return color;
}
ENDCG
}
}

FallBack "Diffuse"
}

Кто может помочь? В шейдерах к сожалению не разбираюсь.

[BornFoRdeatH]

Смысл в таом шейдере да еще и на мобилках? сделайте билборд плашку с альфабленд светящейся текстурой.

[magoga]

а тее 2 варианта, первый - твой шейдер без изменений, просто чтоб работал, но как по мне это довллно нажористо для мобилки, так что на тебе еще оптимайзнутый вариант

Синтаксис:

Синтаксис: [ Показать ]

Используется glsl

 


Shader "Space/PlanetAtmosphere"
{
        Properties
        {
                //_Color("Color", Color) = (0, 0, 0, 1)
                _AtmoColor("Atmosphere Color", Color) = (0.5, 0.5, 1.0, 1)
                _Size("Size", Float) = 0.1
                _Falloff("Falloff", Float) = 5
                _Transparency("Transparency", Float) = 15
        }

SubShader
{
        Tags
        {
                "LightMode" = "Always"
                "Queue" = "Transparent+1"
                "RenderType" = "Transparent"
        }
       
        Pass
        {
                Name "AtmosphereBase"
               
                Cull Front
                Blend SrcAlpha One
               
                CGPROGRAM
                #pragma vertex vert
                #pragma fragment frag

                #include "UnityCG.cginc"
               
                //uniform half4 _Color;
                uniform half4 _AtmoColor;
                uniform half _Size;
                uniform half _Falloff;
                uniform fixed _Transparency;
               
                struct v2f
                {
                        half4 pos : SV_POSITION;
                        fixed3 normal : TEXCOORD0;
                        half3 worldvertpos : TEXCOORD1;
                };
               
                v2f vert(appdata_base v)
                {
                        v2f o;
                       
                        v.vertex.xyz += v.normal*_Size;
                        o.pos = mul (UNITY_MATRIX_MVP, v.vertex);
                        o.normal = v.normal;
                        o.worldvertpos = mul(_Object2World, v.vertex).xyz;
                        return o;
                }
               
                float4 frag(v2f i) : COLOR
                {
                        i.normal = normalize(i.normal);
                        float3 viewdir = normalize(i.worldvertpos-_WorldSpaceCameraPos);
                        float4 color = _AtmoColor;
                        color.a = pow(saturate(dot(viewdir, i.normal)), _Falloff);
                        color.a *= _Transparency*dot(normalize(i.worldvertpos+_WorldSpaceLightPos0), i.normal);
                        return color;
                }
                ENDCG
        }
}

}

 

Синтаксис:

Синтаксис: [ Показать ]

Используется glsl

 
Shader "Space/PlanetAtmosphereOptimized"
{
        Properties
        {
                //_Color("Color", Color) = (0, 0, 0, 1)
                _AtmoColor("Atmosphere Color", Color) = (0.5, 0.5, 1.0, 1)
                _Size("Size", Float) = 0.1
                _Falloff("Falloff", Float) = 5
                _Transparency("Transparency", Float) = 15
        }

SubShader
{
        Tags
        {
                "LightMode" = "Always"
                "Queue" = "Transparent+1"
                "RenderType" = "Transparent"
        }
       
        Pass
        {
                Name "AtmosphereBase"
               
                Cull Front
                Blend SrcAlpha One
               
                CGPROGRAM
                #pragma vertex vert
                #pragma fragment frag

                #include "UnityCG.cginc"
               
                //uniform half4 _Color;
                uniform half4 _AtmoColor;
                uniform half _Size;
                uniform half _Falloff;
                uniform fixed _Transparency;
               
                struct v2f
                {
                        half4 pos : SV_POSITION;
                        fixed3 normal : TEXCOORD0;
                        half3 worldvertpos : TEXCOORD1;
                        fixed3 viewdir: TEXCOORD2;
                        fixed4 color : COLOR;
                };
               
                v2f vert(appdata_base v)
                {
                        v2f o;
                       
                        v.vertex.xyz += v.normal*_Size;
                        o.pos = mul (UNITY_MATRIX_MVP, v.vertex);
                        o.normal = v.normal;
                        o.worldvertpos = mul(_Object2World, v.vertex).xyz;
                        o.viewdir = normalize(o.worldvertpos - _WorldSpaceCameraPos).xyz;      
                        o.color = _AtmoColor;
                        o.color.a = pow(saturate(dot(o.viewdir, o.normal)), _Falloff);
                        o.color.a *= _Transparency * dot(normalize(o.worldvertpos.xyz + _WorldSpaceLightPos0.xyz), o.normal);
                        return o;
                }
               
                fixed4 frag(v2f i) : COLOR
                {                      
                        return i.color;
                }
                ENDCG
        }
}

}

 

[infernno]

а тее 2 варианта, первый - твой шейдер без изменений, просто чтоб работал, но как по мне это довллно нажористо для мобилки, так что на тебе еще оптимайзнутый вариант

http://wiki.unity3d.com/index.php?title=Planet
P.S. Заюзал оптимайзнутый вариант,работает збс)